#!/usr/bin/perl -w
# MasterAddTable
# Vadim Mikheev, (c) 2000, PostgreSQL Inc.

eval '(exit $?0)' && eval 'exec perl -S $0 ${1+"$@"}'
    & eval 'exec perl -S $0 $argv:q'
    if 0;

use strict;
use Pg;
use Getopt::Long;

$| = 1;

my ($debug,$verbose) = (0,0);
my ($help,$masterhost,$masterport,$masteruser,$masterpassword);

my $result = GetOptions(
	"debug!" => \$debug, "verbose!" => \$verbose, "help" => \$help,
	"masterhost=s" => \$masterhost, "masterport=i" => \$masterport,
	"masteruser=s" => \$masteruser, "masterpassword=s" => \$masterpassword,
	);

if (defined($help) || (scalar(@ARGV) < 3)) {
    print "Usage: $0 [options] masterdb table column
Options:
	--masterhost=hostname --masterport=port
	--masteruser=username --masterpassword=string
";
    exit ((scalar(@ARGV) < 3)? 1:0);
}

my $dbname = $ARGV[0];
my $table = $ARGV[1];
my $keyname = $ARGV[2];

my $minfo = "dbname=$dbname";
$minfo = "$minfo host=$masterhost" if (defined($masterhost));
$minfo = "$minfo port=$masterport" if (defined($masterport));
$minfo = "$minfo user=$masteruser" if (defined($masteruser));
$minfo = "$minfo password=$masterpassword" if (defined($masterpassword));

my $conn = Pg::connectdb($minfo);
if ($conn->status != PGRES_CONNECTION_OK) {
    print STDERR "Failed opening $minfo\n";
    exit 1;
}

$result = $conn->exec("BEGIN");
die $conn->errorMessage if $result->resultStatus ne PGRES_COMMAND_OK;

$result = $conn->exec("select pgc.oid, pga.attnum from pg_class pgc" . 
		      ", pg_attribute pga where pgc.relname = '$table'" .
		      " and pgc.oid = pga.attrelid" . 
		      " and pga.attname = '$keyname'");
die $conn->errorMessage if $result->resultStatus ne PGRES_TUPLES_OK;

my @row = $result->fetchrow;
die "Can't find table/key\n" if ! defined $row[0] || ! defined $row[1];

$result = $conn->exec("create trigger _RSERV_TRIGGER_T_ after" . 
		      " insert or update or delete on \"$table\"" .
		      " for each row execute procedure" . 
		      " _rserv_log_('$row[1]')");
die $conn->errorMessage if $result->resultStatus ne PGRES_COMMAND_OK;

$result = $conn->exec("insert into _RSERV_TABLES_ (tname, cname, reloid, key)" . 
		      " values ('$table', '$keyname', $row[0], $row[1])");
die $conn->errorMessage if $result->resultStatus ne PGRES_COMMAND_OK;

$result = $conn->exec("COMMIT");
die $conn->errorMessage if $result->resultStatus ne PGRES_COMMAND_OK;

exit(0);
