#!/usr/bin/perl -w
# PrepareSnapshot
# Vadim Mikheev, (c) 2000, PostgreSQL Inc.

eval '(exit $?0)' && eval 'exec perl -S $0 ${1+"$@"}'
    & eval 'exec perl -S $0 $argv:q'
    if 0;

BEGIN {
	my $basedir = $0; $basedir =~ s#/[^/]+$##;
	unshift(@INC, "$basedir/../share");
}

use strict;
use IO::File;
use Getopt::Long;
use RServ;
use Sys::Hostname;

$| = 1;

my ($debug,$verbose) = (0,0);
my ($help,$masterhost,$masterport,$masteruser,$masterpassword,
	$slavehost,$slaveport,$slaveuser,$slavepassword);
my $snapshot;

my $result = GetOptions(
	"debug!" => \$debug, "verbose!" => \$verbose, "help" => \$help,
	"masterhost=s" => \$masterhost, "masterport=i" => \$masterport,
	"masteruser=s" => \$masteruser, "masterpassword=s" => \$masterpassword,
	"snapshot=s" => \$snapshot,
	);

if (defined($help) || (scalar(@ARGV) < 2)) {
    print "Usage: $0 [options] masterdb slavedb
Options:
	--masterhost=hostname --masterport=port
	--masteruser=username --masterpassword=string
	--snapshot=snapshot
";
    exit ((scalar(@ARGV) < 2)? 1:0);
}

$RServ::quiet = !$verbose;
if ($debug) {
	$RServ::quiet = 0;
	no warnings 'vars';
	$RServ::debug = $debug;
}

my $master = $ARGV[0] || "master";
my $slave = $ARGV[1] || "slave";

my $minfo = "dbname=$master";
$minfo = "$minfo host=$masterhost" if (defined($masterhost));
$minfo = "$minfo port=$masterport" if (defined($masterport));
$minfo = "$minfo user=$masteruser" if (defined($masteruser));
$minfo = "$minfo password=$masterpassword" if (defined($masterpassword));

my $sinfo = "dbname=$slave";
$sinfo = "$sinfo host=$slavehost" if (defined($slavehost));
$sinfo = "$sinfo port=$slaveport" if (defined($slaveport));
$sinfo = "$sinfo user=$slaveuser" if (defined($slaveuser));
$sinfo = "$sinfo password=$slavepassword" if (defined($slavepassword));

my $mconn = Pg::connectdb($minfo);
if ($mconn->status != Pg::PGRES_CONNECTION_OK) {
    print STDERR "Failed opening $minfo\n";
    exit 1;
}
my $sconn = Pg::connectdb($sinfo);
if ($sconn->status != Pg::PGRES_CONNECTION_OK) {
    print STDERR "Failed opening $minfo\n";
    exit 1;
}

my $outf;
if (defined($snapshot)) {
    $outf = new IO::File;    
    $outf->open("> $snapshot");
} else {
    $outf = *STDOUT;
}

my $hostname = defined($slavehost) ? $slavehost : hostname;
my $slaveId  = GetSlaveId($mconn, $slave, $hostname);
if (! $slaveId) {
	print STDERR "Can't find SlaveId for db '$slave' on host $hostname. Is this database slave?\n";
	exit 1;
}
die "Unknown SlaveId $slaveId for host $hostname" if ($slaveId < 0);

my $res = PrepareSnapshot ($mconn, $sconn, $outf, $slaveId);

if ($res == 0)
{
    printf STDERR "Sync-ed\n";
    exit(0);
}
if ($res > 0)
{
    printf STDERR "Snapshot dumped.\n";
    exit(0);
}

printf STDERR "ERROR\n";
exit(1);
